Know-how für Terms-Produkte

Inhalt  Terms-Homepage          Kapitel:  1  2  3  4  5   6   7   8

1.3 Beispielskript zur Installation von TermsCall im Netzwerk

@ echo off

REM ################################################
REM # Beispielskript zur Installation von TermsCall
REM # Für WfW 3.11 Windows95/98 WindowsNT4.0/5.0
REM #
REM # Im Quellverzeichnis sollten sich die Unterverzeichnisse
REM # 16bit und 32bit befinden.
REM # Jedes dieser Unterverzeichnisse sollte die entsprechenden
REM # Dateien für die Installation enthalten.
REM #
REM # 16 bit: listener.exe listener.ini autostar.grp
REM #
REM # 32 bit: listener.exe TermsListener.ini listener.lnk
REM #         caller.exe TermsCaller.ini caller.lnk liste
REM #
REM # Achtung: Skripte verwenden OEM-Zeichensatz!!!
REM ###########################################

REM #  Hier entsprechende Änderungen vornehmen

REM # Das Skript kann durch Aktivieren des subst-Befehls zur direkten
REM # Installation von Diskette verwendet werden.
REM subst T: A:\

REM # Quellverzeichnis auf dem Server
set SHARE=\\Server\Freigabename

REM # Installationsverzeichnis auf den Zielrechnern
set DEST=C:\Tcall
set DEST32=C:\TermsCall

REM # Mit LISTENERONLY=YES wird nur der Listener, mit HOSTSONLY=YES
REM # nur die Rechnerliste verteilt.
set LISTENERONLY=NO
set HOSTSONLY=NO

REM #  Ab hier keine Änderungen vornehmen
REM ###########################################


REM # Installationslaufwerk mappen
net use T: /DELETE > nul
net use T: %SHARE% /YES > nul

REM # Windows-Version bestimmen
ver > ver.txt
find "DOS" ver.txt > nul
if errorlevel 2 goto end
if errorlevel 1 goto not3x
if errorlevel 0 goto found3x
goto end
:not3x
find "95" ver.txt > nul
if errorlevel 2 goto end
if errorlevel 1 goto not95
if errorlevel 0 goto found95
goto end
:not95
find "98" ver.txt > nul
if errorlevel 2 goto end
if errorlevel 1 goto not98
if errorlevel 0 goto found98
goto end
:not98
find "NT" ver.txt > nul
if errorlevel 2 goto end
if errorlevel 1 goto end
if errorlevel 0 goto foundNT
goto end
:found95
goto found9x
goto end
:found98
goto found9x
goto end


REM # INSTALLATION

REM # Windows3x
:found3x
if exist %DEST%\listener.exe goto end > nul
mkdir %DEST%
copy /Y T:\16bit\listener.exe %DEST%\listener.exe
copy /Y T:\16bit\listener.ini %DEST%\listener.ini
REM # seltsamerweise funktioniert es so, aber nicht mit Backslash!?
copy %WINDIR%autostar.grp %windir%autostar.bak
copy /Y T:\16bit\autostar.grp %windir%autostar.grp
goto end

REM # Windows9x
:found9x
if %HOSTSONLY%==YES goto liste
if exist %DEST32%\listener.exe goto caller > nul
mkdir %DEST32%
copy /Y T:\32bit\listener.exe %DEST32%\listener.exe
copy /Y T:\32bit\TermsL~1.ini %DEST32%\TermsListener.ini
copy /Y T:\32bit\listener.lnk %WINDIR%\Startmenü\Programme\Autostart\listener.lnk
REM # Listener wird anschließend durch das System gestartet
:caller
if %LISTENERONLY%==YES goto end
if exist %DEST32%\caller.exe goto end > nul
copy /Y T:\32bit\caller.exe %DEST32%\caller.exe
copy /Y T:\32bit\TermsC~1.ini %DEST32%\TermsCaller.ini
copy /Y T:\32bit\caller.lnk %WINDIR%\Desktop\caller.lnk
mkdir %WINDIR%\Startmenü\Programme\TermsCall
copy /Y T:\32bit\caller.lnk %WINDIR%\Startmenü\Programme\TermsCall\caller.lnk
:liste
copy /Y T:\32bit\liste %DEST32%\liste
goto end

REM # WindowsNT
:foundNT
if %HOSTSONLY%==YES goto liste
if exist %DEST32%\listener.exe goto caller > nul
mkdir %DEST32%
copy T:\32bit\listener.exe %DEST32%\listener.exe
copy T:\32bit\TermsListener.ini %DEST32%\TermsListener.ini
copy T:\32bit\listener.lnk "%WINDIR%\Profiles\All Users\Startmenü\Programme\Autostart\listener.lnk"
start %DEST32%\listener.exe
:caller
if %LISTENERONLY%==YES goto end
if exist %DEST32%\caller.exe goto end > nul
copy T:\32bit\caller.exe %DEST32%\caller.exe
copy T:\32bit\TermsCaller.ini %DEST32%\TermsCaller.ini
copy T:\32bit\caller.lnk "%WINDIR%\Profiles\All Users\Desktop\caller.lnk"
mkdir "%WINDIR%\Profiles\All Users\Startmenü\Programme\TermsCall"
copy T:\32bit\caller.lnk "%WINDIR%\Profiles\All Users\Startmenü\Programme\TermsCall\caller.lnk"
:liste
copy T:\32bit\liste %DEST32%\liste
goto end


:end

REM # Datei mit Versionsinformation löschen
del ver.txt
REM # Installationslaufwerk trennen
net use T: /DELETE /YES > nul
subst T: /D > nul

REM # REM entfernen für DEBUG
REM pause

exit

Inhalt  Terms-Homepage          Kapitel:  1  2  3  4  5   6   7   8